dsview/PKGBUILD
Jake 83ebff9d8c Update: dsview 1:1.2.1-1
upstream release
2022-09-10 23:00:37 +02:00

47 lines
1.2 KiB
Bash

# Maintainer: Cody Schafer <aur@codyps.com>
# Maintainer: Jake <aur@ja-ke.tech>
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>
# epoch 0: up to 1.11
# epoch 1: 1.2.0
epoch=1
pkgname=dsview
pkgver=1.2.1
pkgrel=1
pkgdesc="Client software that supports the DreamSourceLab logic analyzer"
arch=('i686' 'x86_64')
url="http://www.dreamsourcelab.com/"
license=('GPL3')
depends=('hicolor-icon-theme' 'qt5-base' 'fftw' 'python')
makedepends=('cmake' 'ninja' 'boost')
source=(
"DSView-$pkgver.tar.gz::https://github.com/DreamSourceLab/DSView/archive/v${pkgver}.tar.gz"
)
sha384sums=('a0cdd4d9e28641ab42bb94354398b470be28ef2ec296544e8eea55186aacc1f2709fdb7f142bf345d6680c15e36cbd65')
prepare() {
sed -i 's#MODE="0666"#TAG+="uaccess"#' \
"DSView-${pkgver}/DSView/DreamSourceLab.rules"
}
build() {
cmake -B build -S "DSView-${pkgver}" \
-GNinja \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-Wno-dev
cmake --build build
}
check() {
ctest --test-dir build --output-on-failure
}
package() {
DESTDIR="$pkgdir" cmake --install build
ln -s "DSView" "${pkgdir}/usr/bin/${pkgname}"
}
# vim:set ts=2 sw=2 et: